Welcome to our community

Be a part of something great, join today!

[SOLVED] Poisson's kernel

dwsmith

Well-known member
Feb 1, 2012
1,673
$$
p(r,\theta) = \frac{1}{2\pi}\sum_{n = -\infty}^{\infty}r^{|n|}e^{in\theta} = \frac{1}{2\pi}\left[\frac{1 - r^2}{1 - 2r\cos\theta + r^2}\right].
$$
So I produced the graph but it wont animate.

Code:
MyR = Table[r, {r, 0, 1, .1}];

u[\[Theta]_] = 1/(2*Pi)*((1 - r^2)/(1 - 2*r*Cos[\[Theta]] + r^2));
Plot[u[MyR, \[Theta]], {\[Theta], -Pi/2, Pi/2}, 
 PlotRange -> {0, 3.25}, PlotStyle -> {Red}, AspectRatio -> 2/3]
Poissons kernel.jpg

Code:
Animate[Plot[u[\[Theta]], {\[Theta], -Pi/2, Pi/2}, 
  PlotRange -> {0, 3.25}, GridLines -> Automatic, Frame -> True, 
  PlotStyle -> {Thick, Red}], {r, 0, 1, 0.1}, 
 AnimationRunning -> False]
This code doesn't produce any errors or Mathematica complaining but nothing happens when I hit play.
 
Last edited:

Sudharaka

Well-known member
MHB Math Helper
Feb 5, 2012
1,621
$$
p(r,\theta) = \frac{1}{2\pi}\sum_{n = -\infty}^{\infty}r^{|n|}e^{in\theta} = \frac{1}{2\pi}\left[\frac{1 - r^2}{1 - 2r\cos\theta + r^2}\right].
$$
So I produced the graph but it wont animate.

Code:
MyR = Table[r, {r, 0, 1, .1}];

u[\[Theta]_] = 1/(2*Pi)*((1 - r^2)/(1 - 2*r*Cos[\[Theta]] + r^2));
Plot[u[MyR, \[Theta]], {\[Theta], -Pi/2, Pi/2}, 
 PlotRange -> {0, 3.25}, PlotStyle -> {Red}, AspectRatio -> 2/3]
View attachment 378

Code:
Animate[Plot[u[\[Theta]], {\[Theta], -Pi/2, Pi/2}, 
  PlotRange -> {0, 3.25}, GridLines -> Automatic, Frame -> True, 
  PlotStyle -> {Thick, Red}], {r, 0, 1, 0.1}, 
 AnimationRunning -> False]
This code doesn't produce any errors or Mathematica complaining but nothing happens when I hit play.
Hi dwsmith, :)

I don't use Mathematica but seeing this question go unanswered I posted this in the Google Mathematica group. Here are the replies.

Kind Regards,
Sudharaka.


Reply 1:

myR = Table[r, {r, 0, 1, .1}];

u[r_, \[Theta]_] = 1/(2*Pi)*((1 - r^2)/
(1 - 2*r*Cos[\[Theta]] + r^2));

Plot[Evaluate[
Tooltip[u[#, \[Theta]], #] & /@ myR],
{\[Theta], -Pi/2, Pi/2},
PlotRange -> {0, 3.25},
AspectRatio -> 2/3,
Frame -> True,
Axes -> False]

Plot3D[u[r, \[Theta]],
{\[Theta], -Pi/2, Pi/2},
{r, 0, 1},
PlotRange -> {0, 4},
AspectRatio -> 2/3,
ClippingStyle -> None]

Animate[
Plot[u[r, \[Theta]], {\[Theta], -Pi/2, Pi/2},
PlotRange -> {0, 3.25},
GridLines -> Automatic,
Frame -> True,
PlotStyle -> {Thick, Red}],
{r, 0, 1, 0.1},
AnimationRunning -> False]

Manipulate[
Plot[u[r, \[Theta]], {\[Theta], -Pi/2, Pi/2},
PlotRange -> {0, 3.25},
GridLines -> Automatic,
Frame -> True,
PlotStyle -> {Thick, Red}],
{r, 0, 1, 0.01, Appearance -> "Labeled"}]


Reply 2:


You need to define u as a function of two variables.

u[r_,theta_]= ...
as in

MyR = Table[r, {r, 0, 1, .1}];

u[r_ ,\[Theta]_] = 1/(2*Pi)*((1 - r^2)/(1 - 2*r*Cos[\[Theta]] + r^2));
Plot[u[MyR, \[Theta]], {\[Theta], -Pi/2, Pi/2},
PlotRange -> {0, 3.25}, PlotStyle -> {Red}, AspectRatio -> 2/3]



Then

Animate[Plot[u[r,\[Theta]], {\[Theta], -Pi/2, Pi/2}, PlotRange -> {0, 3.25}, GridLines -> Automatic, Frame -> True, PlotStyle -> {Thick, Red}], {r, 0, 1, 0.1}, AnimationRunning -> False]